{$CLEO .qa}
{$USE CLEO+}
{$USE Audio}
{$USE newOpcodes}
{$USE ini}

0000: NOP

script_name "StrtFH"

// By ArtemQa146

const
    Fighter_1 = 31@
    Fighter_2 = 30@
    Watcher_1 = 29@
    Watcher_2 = 28@
    Watcher_3 = 27@
    progress = 26@
    coords_x = 25@
    coords_y = 24@
    coords_z = 23@
    AudioMusic = 22@
    volume_1 = 21@
    money_1 = 20@
    select = 19@
end

0087: coords_x = 0@ // (float)
0087: coords_y = 1@ // (float)
0087: coords_z = 2@ // (float)

if
    0E4D: random_percent 3@
then
else
    repeat
    wait 0
    until not locate_char_distance_to_coordinates $PLAYER_ACTOR pos coords_x coords_y coords_z radius 150.0
    0A93: terminate_this_custom_script
end
    
        repeat
        wait 0
        04ED: load_animation  "PedEventsMod"
        until 04EE:   animation "PedEventsMod" loaded
    
        0209: 1@ = random_int_in_ranges 1 5
        if 1@ == 1
        then 5@ = 28
        end
        if 1@ == 2
        then 5@ = 30
        end
        if 1@ == 3
        then 5@ = 19
        end
        if 1@ == 4
        then 5@ = 29
        end
        
        model.Load(5@)
        model.Load(21)
        model.Load(48)
        model.Load(60)
        if
            not model.Available(5@)
        then
            repeat
            wait 0
            model.Load(5@)
            until model.Available(5@)
        end
        if
            not model.Available(21)
        then
            repeat
            wait 0
            model.Load(21)
            until model.Available(21)
        end
        if
            not model.Available(48)
        then
            repeat
            wait 0
            model.Load(48)
            until model.Available(48)
        end
        if
            not model.Available(60)
        then
            repeat
            wait 0
            model.Load(60)
            until model.Available(60)
        end
        038B: load_requested_models

        009A: Fighter_1 = create_actor_pedtype 21 model 5@ at coords_x coords_y coords_z
        0208: 1@ = random_float_in_ranges 0.0 360.0
        0173: set_actor Fighter_1 Z_angle_to 1@
        0172: 6@ = actor Fighter_1 Z_angle
        6@ += 180.0
        04C4: store_coords_to 2@ 3@ 4@ from_actor Fighter_1 with_offset -0.4 1.3 0.0
        model.Destroy(5@)
        
        0209: 1@ = random_int_in_ranges 1 5
        if 1@ == 1
        then 5@ = 28
        end
        if 1@ == 2
        then 5@ = 30
        end
        if 1@ == 3
        then 5@ = 19
        end
        if 1@ == 4
        then 5@ = 29
        end
        
        model.Load(5@)
        038B: load_requested_models
        
        009A: Fighter_2 = create_actor_pedtype 21 model 5@ at 2@ 3@ 4@
        0173: set_actor Fighter_2 Z_angle_to 6@
        model.Destroy(5@)
        
        04C4: store_coords_to 2@ 3@ 4@ from_actor Fighter_1 with_offset -2.0 4.0 0.0
        009A: Watcher_1 = create_actor_pedtype 21 model 21 at 2@ 3@ 4@
        0173: set_actor Watcher_1 Z_angle_to 286.0
        
        04C4: store_coords_to 2@ 3@ 4@ from_actor Fighter_1 with_offset 4.0 1.5 0.0
        009A: Watcher_2 = create_actor_pedtype 21 model 48 at 2@ 3@ 4@
        0173: set_actor Watcher_2 Z_angle_to 137.0
        
        04C4: store_coords_to 2@ 3@ 4@ from_actor Fighter_1 with_offset -2.0 -4.0 0.0
        009A: Watcher_3 = create_actor_pedtype 21 model 60 at 2@ 3@ 4@
        0173: set_actor Watcher_3 Z_angle_to 88.0
        
        04C4: store_coords_to 2@ 3@ 4@ from_actor Fighter_1 with_offset 0.0 0.0 0.0
        04C4: store_coords_to 4@ 5@ 6@ from_actor Watcher_1 with_offset 0.0 0.0 0.0
        0E27: get_angle_from_two_coords 4@ 5@ and 2@ 3@ to 6@
        0173: set_actor Watcher_1 Z_angle_to 6@
        
        04C4: store_coords_to 2@ 3@ 4@ from_actor Fighter_1 with_offset 0.0 0.0 0.0
        04C4: store_coords_to 4@ 5@ 6@ from_actor Watcher_2 with_offset 0.0 0.0 0.0
        0E27: get_angle_from_two_coords 4@ 5@ and 2@ 3@ to 6@
        0173: set_actor Watcher_2 Z_angle_to 6@

        04C4: store_coords_to 2@ 3@ 4@ from_actor Fighter_1 with_offset 0.0 0.0 0.0
        04C4: store_coords_to 4@ 5@ 6@ from_actor Watcher_3 with_offset 0.0 0.0 0.0
        0E27: get_angle_from_two_coords 4@ 5@ and 2@ 3@ to 6@
        0173: set_actor Watcher_3 Z_angle_to 6@

        0E24: fix_char Fighter_1 ground 1 brightness 1 and_fade_in 0
        0E24: fix_char Fighter_2 ground 1 brightness 1 and_fade_in 0
        0E24: fix_char Watcher_1 ground 1 brightness 1 and_fade_in 0
        0E24: fix_char Watcher_2 ground 1 brightness 1 and_fade_in 0
        0E24: fix_char Watcher_3 ground 1 brightness 1 and_fade_in 0
        
        0812: AS_actor Fighter_1 perform_animation "Fight_idle" IFP "PedEventsMod" framedelta 2.0 loopA 1 lockX 1 lockY 1 lockF 0 time -1  // versionB
        0812: AS_actor Fighter_2 perform_animation "Fight_idle_2" IFP "PedEventsMod" framedelta 2.0 loopA 1 lockX 1 lockY 1 lockF 0 time -1  // versionB
        0812: AS_actor Watcher_1 perform_animation "Fight_stay_1" IFP "PedEventsMod" framedelta 2.0 loopA 1 lockX 0 lockY 0 lockF 0 time -1  // versionB
        0812: AS_actor Watcher_2 perform_animation "Fight_stay_2" IFP "PedEventsMod" framedelta 2.0 loopA 1 lockX 0 lockY 0 lockF 0 time -1  // versionB
        0812: AS_actor Watcher_3 perform_animation "Fight_book" IFP "PedEventsMod" framedelta 2.0 loopA 1 lockX 0 lockY 0 lockF 0 time -1  // versionB
        0AF0: 1@ = read_int_from_ini_file "cleo\PedsModels.ini" section "Models" key "cop2"
        0F02: create_render_object_to_char_bone_from_special Watcher_3 special_model 1@ bone 34 offset 0.25 0 0 rotation 0 180.0 350.0 store_to 1@
        progress = 0
        
        0AC1: AudioMusic = load_audio_stream_with_3d_support "SQ\FC1.mp3"
        0AC4: link_3d_audio_stream AudioMusic to_actor Fighter_1
        0AC0: audio_stream AudioMusic looped 1
        0AAD: set_audio_stream AudioMusic state 1
        
        model.Destroy(21)
        model.Destroy(48)
        model.Destroy(60)
        
        repeat
        wait 0
        if and
            056D:   actor Fighter_1 defined
            056D:   actor Fighter_2 defined
            056D:   actor Watcher_1 defined
            056D:   actor Watcher_2 defined
            056D:   actor Watcher_3 defined
        then
        
            if or
                051A:   actor Fighter_1 damaged_by_actor $player_actor
                051A:   actor Fighter_2 damaged_by_actor $player_actor
                051A:   actor Watcher_1 damaged_by_actor $player_actor
                051A:   actor Watcher_2 damaged_by_actor $player_actor
                051A:   actor Watcher_3 damaged_by_actor $player_actor
            then
                05E2: AS_actor Fighter_1 kill_actor $player_actor
                05E2: AS_actor Fighter_2 kill_actor $player_actor
                05E2: AS_actor Watcher_1 kill_actor $player_actor
                05E2: AS_actor Watcher_2 kill_actor $player_actor
                05E2: AS_actor Watcher_3 kill_actor $player_actor
                repeat
                wait 0
                until not locate_char_distance_to_coordinates $player_actor pos coords_x coords_y coords_z radius 100.0
                break
            end
            
            if or
                0457:   player $PLAYER_CHAR aiming_at_actor Fighter_1
                0457:   player $PLAYER_CHAR aiming_at_actor Fighter_2
                0457:   player $PLAYER_CHAR aiming_at_actor Watcher_1
                0457:   player $PLAYER_CHAR aiming_at_actor Watcher_2
                0457:   player $PLAYER_CHAR aiming_at_actor Watcher_3
            then
                0E83: get_current_char_weaponinfo $PLAYER_ACTOR store_to 1@
                0E89: get_weaponinfo_fire_type 1@ store_to 2@ //     
                if or
                    2@ == 1 //  
                    2@ == 3 //   (  ..)
                then
                    05E2: AS_actor Fighter_1 kill_actor $player_actor
                    05E2: AS_actor Fighter_2 kill_actor $player_actor
                    05E2: AS_actor Watcher_1 kill_actor $player_actor
                    05E2: AS_actor Watcher_2 kill_actor $player_actor
                    05E2: AS_actor Watcher_3 kill_actor $player_actor
                    repeat
                    wait 0
                    until not locate_char_distance_to_coordinates $player_actor pos coords_x coords_y coords_z radius 100.0
                    break
                end
            end
        
            080E: get_actor Fighter_1 ped_event_to 1@
            080E: get_actor Fighter_2 ped_event_to 2@
            080E: get_actor Watcher_1 ped_event_to 3@
            if or
                1@ == 49
                1@ == 9
                2@ == 49
                2@ == 9
                3@ == 49
                3@ == 9
            then
                break
            end
            
            080E: get_actor Watcher_2 ped_event_to 1@
            080E: get_actor Watcher_3 ped_event_to 2@
            if or
                1@ == 49
                1@ == 9
                2@ == 49
                2@ == 9
            then
                break
            end
        
            if or
                0118:   actor Fighter_1 dead
                0118:   actor Fighter_2 dead
                0118:   actor Watcher_1 dead
                0118:   actor Watcher_2 dead
                0118:   actor Watcher_3 dead
                not $ACTIVE_INTERIOR == 0
            then
                break
            end

            //   ,    3       ,   
            04C4: store_coords_to 1@ 2@ 3@ from_actor Fighter_1 with_offset 0.0 0.0 0.0
            0EB2: get_offset_from_camera_in_world_coords 0.0 0.0 0.0 store_to 4@ 5@ 6@
            050A: 1@ = distance_between_XYZ 1@ 2@ 3@ and_XYZ 4@ 5@ 6@
            1@ /= 50.0
            2@ = 1.0
            0063: 2@ -= 1@  // (float)
            if
                2@ < 0.0
            then
                2@ = 0.0
            end
            0ABC: set_audio_stream AudioMusic volume 2@
            0087: volume_1 = 2@ // (float)

            if 0611:   actor Fighter_1 performing_animation "Fight_idle"
            then 0393: actor Fighter_1 perform_animation "Fight_idle" at 1.45 times_normal_rate
            end
            if 0611:   actor Fighter_2 performing_animation "Fight_idle_2"
            then 0393: actor Fighter_2 perform_animation "Fight_idle_2" at 1.45 times_normal_rate
            end
            if 0611:   actor Fighter_1 performing_animation "Fight_down"
            then 0393: actor Fighter_1 perform_animation "Fight_down" at 1.4 times_normal_rate
            end
            if 0611:   actor Fighter_2 performing_animation "Fight_down_2"
            then 0393: actor Fighter_2 perform_animation "Fight_down_2" at 1.4 times_normal_rate
            end
            if 0611:   actor Fighter_1 performing_animation "Fight_uper_2"
            then 0393: actor Fighter_1 perform_animation "Fight_uper_2" at 1.5 times_normal_rate
            end
            if 0611:   actor Fighter_2 performing_animation "Fight_uper"
            then 0393: actor Fighter_2 perform_animation "Fight_uper" at 1.5 times_normal_rate
            end
            
            if
                progress == 0
            then
                04C4: store_coords_to 1@ 2@ 3@ from_actor Watcher_3 with_offset 1.0 0.0 0.0
                4@ = 0
                if 0EEA: locate_char_distance_to_coordinates $player_actor pos 1@ 2@ 3@ radius 10.0
                then 4@ = 1
                end
                if and
                    010A:   player $PLAYER_CHAR money > 99
                    0102:   actor $PLAYER_ACTOR in_sphere 1@ 2@ 3@ radius 0.7 0.7 1.0 sphere 4@ stopped_on_foot
                then
                    01B4: set_player $PLAYER_CHAR can_move 0
                    0581: enable_radar 0
                    0826: enable_hud 0
                    03BF: set_player $PLAYER_CHAR ignored_by_everyone 1
                    money_1 = 100
                    select = 1
                    0512: show_permanent_text_box 'STFGHQ2'  // If your health reaches zero, you will pass out and you will be treated at the local medical center.
                    timerb = 0
                    04C4: store_coords_to 7@ 8@ 9@ from_actor Watcher_3 with_offset -1.5 0.0 0.0
                    0172: 10@ = actor Watcher_3 Z_angle

                    repeat
                    wait 0
                    if and
                        056D:   actor Fighter_1 defined
                        056D:   actor Fighter_2 defined
                        056D:   actor Watcher_1 defined
                        056D:   actor Watcher_2 defined
                        056D:   actor Watcher_3 defined
                    then

                        if 010A:   player $PLAYER_CHAR money > money_1
                        then 0AD1: show_formatted_text_highpriority "$%d" time 500 money_1
                        else 0AD1: show_formatted_text_highpriority "~r~$%d" time 500 money_1
                        end
                        
                        if
                            00E1:   player 0 pressed_key 15
                        then
                            break
                        end
                        
                        if and
                            00E1:   player 0 pressed_key 16
                            010A:   player $PLAYER_CHAR money > money_1
                        then
                            money_1 *= -1
                            0109: player $PLAYER_CHAR money += money_1
                            money_1 *= -1
                            progress = 146
                            break
                        end

                        
                        00E2: get_player 0 key 0 state_to 1@
                        if and
                            timerb > 300
                            1@ > 100
                        then
                            if select == 1
                            then select = 2
                            else select = 1
                            end
                            timerb = 0
                        end
                        if and
                            timerb > 300
                            1@ < -100
                        then
                            if select == 1
                            then select = 2
                            else select = 1
                            end
                            timerb = 0
                        end

                        
                        if 0611:   actor Fighter_1 performing_animation "Fight_idle"
                        then 0393: actor Fighter_1 perform_animation "Fight_idle" at 1.45 times_normal_rate
                        end
                        if 0611:   actor Fighter_2 performing_animation "Fight_idle_2"
                        then 0393: actor Fighter_2 perform_animation "Fight_idle_2" at 1.45 times_normal_rate
                        end
                        
                        04C4: store_coords_to 1@ 2@ 3@ from_actor Watcher_3 with_offset 0.0 -2.0 3.0
                        if select == 1
                        then 04C4: store_coords_to 4@ 5@ 6@ from_actor Fighter_1 with_offset 0.0 0.0 0.0
                        else 04C4: store_coords_to 4@ 5@ 6@ from_actor Fighter_2 with_offset 0.0 0.0 0.0
                        end
                        015F: set_camera_position 1@ 2@ 3@ rotation 0.0 0.0 0.0
                        0160: set_camera_point_at 4@ 5@ 6@ switchstyle 2
                        
                        if
                            select == 1
                        then
                            04C4: store_coords_to 1@ 2@ 3@ from_actor Fighter_1 with_offset 0.0 0.0 1.5
                            if convert_3d_to_screen_2d 1@ 2@ 3@ checkNearClip 1 checkFarClip 1 store_2d_to 1@ 2@ size_to 3@ 4@
                            then gosub @Text
                            end
                        else
                            04C4: store_coords_to 1@ 2@ 3@ from_actor Fighter_2 with_offset 0.0 0.0 1.5
                            if convert_3d_to_screen_2d 1@ 2@ 3@ checkNearClip 1 checkFarClip 1 store_2d_to 1@ 2@ size_to 3@ 4@
                            then gosub @Text
                            end
                        end
                        
                        if and
                            timerb > 100
                            00E1:   player 0 pressed_key 11 // Y
                        then
                            money_1 += 100
                            if money_1 > 2000
                            then money_1 = 2000
                            end
                            timerb = 0
                        end
                        if and
                            timerb > 100
                            00E1:   player 0 pressed_key 10 // N
                        then
                            money_1 -= 100
                            if money_1 < 100
                            then money_1 = 100
                            end
                            timerb = 0
                        end

                    else
                        break
                    end
                    until not player.Defined(0)
                    01B4: set_player $PLAYER_CHAR can_move 1
                    0581: enable_radar 1
                    0826: enable_hud 1
                    03BF: set_player $PLAYER_CHAR ignored_by_everyone 0
                    02EB: restore_camera_with_jumpcut
                    03E6: remove_text_box
                    timera = 0
                    00A1: put_actor $PLAYER_ACTOR at 7@ 8@ 9@
                    0173: set_actor $PLAYER_ACTOR Z_angle_to 10@
                    0E24: fix_char $PLAYER_ACTOR ground 1 brightness 1 and_fade_in 0
                    if progress == 146
                    then 03E5: show_text_box 'STFGHQ4'  // Respect can be earned be passing certain missions, killing rival gangs members, gaining territory and tagging.
                    end
                    continue
                else
                    if and
                        0101:   actor $PLAYER_ACTOR in_sphere 1@ 2@ 3@ radius 0.7 0.7 1.0 sphere 4@ stopped
                        810A:   not player $PLAYER_CHAR money > 99
                    then
                        00BC: show_text_highpriority GXT "STFGHQ3" time 500 flag 1  // 
                    end
                end
            end
            
            if and
                progress == 146
                0611:   actor Fighter_1 performing_animation "Fight_idle"
            then
                0613: 1@ = actor Fighter_1 animation "Fight_idle" time
                if
                    1@ > 0.9
                then
                    0E97: clear_char_secondary_tasks Fighter_1
                    0E97: clear_char_secondary_tasks Fighter_2
                    0172: 1@ = actor Fighter_1 Z_angle
                    1@ -= 90.0
                    0173: set_actor Fighter_1 Z_angle_to 1@
                    1@ += 180.0
                    0173: set_actor Fighter_2 Z_angle_to 1@
                    0812: AS_actor Fighter_1 perform_animation "Fight_down" IFP "PedEventsMod" framedelta 2.0 loopA 0 lockX 1 lockY 1 lockF 0 time -1  // versionB
                    0812: AS_actor Fighter_2 perform_animation "Fight_down_2" IFP "PedEventsMod" framedelta 2.0 loopA 0 lockX 1 lockY 1 lockF 1 time -1  // versionB
                    if 0E4D: random_percent 50
                    then progress = 1
                    else progress = 10
                    end
                end
            end
            
            
            
            if and
                progress == 1
                0611:   actor Fighter_1 performing_animation "Fight_down"
            then
                0613: 1@ = actor Fighter_1 animation "Fight_down" time
                if
                    1@ > 0.9
                then
                    0812: AS_actor Fighter_1 perform_animation "Fight_win" IFP "PedEventsMod" framedelta 2.0 loopA 0 lockX 1 lockY 1 lockF 0 time -1  // versionB
                    progress = 2
                end
            end
            if and
                progress == 2
                0611:   actor Fighter_1 performing_animation "Fight_win"
            then
                0613: 1@ = actor Fighter_1 animation "Fight_win" time
                if
                    1@ > 0.9
                then
                    progress = 3
                    034F: destroy_actor_with_fade Fighter_2
                    if
                        select == 1
                    then 
                        money_1 *= 2
                        0109: player $PLAYER_CHAR money += money_1
                        money_1 /= 2
                        01E3: show_text_1number_styled GXT 'WINNER' number money_1 time 2000 style 5  // NEW HIGH SCORE!!~n~~w~~1~
                    else
                        03FE: set_actor Watcher_3 money money_1
                        00BA: show_text_styled GXT "NOWIN" time 2000 style 5  // Beefy Baron
                    end
                    break
                end
            end
            
            
            if and
                progress == 10
                0611:   actor Fighter_1 performing_animation "Fight_down"
            then
                0613: 1@ = actor Fighter_1 animation "Fight_down" time
                if
                    1@ > 0.9
                then
                    progress = 11
                    0172: 1@ = actor Fighter_2 Z_angle
                    1@ += 180.0
                    0173: set_actor Fighter_1 Z_angle_to 1@
                    04C4: store_coords_to 1@ 2@ 3@ from_actor Fighter_2 with_offset 0.2 1.2 0.0
                    00A1: put_actor Fighter_1 at 1@ 2@ 3@
                    0E24: fix_char Fighter_1 ground 1 brightness 1 and_fade_in 0
                    0812: AS_actor Fighter_2 perform_animation "Fight_uper" IFP "PedEventsMod" framedelta 2.0 loopA 0 lockX 1 lockY 1 lockF 0 time -1  // versionB
                    0812: AS_actor Fighter_1 perform_animation "Fight_uper_2" IFP "PedEventsMod" framedelta 2.0 loopA 0 lockX 1 lockY 1 lockF 1 time -1  // versionB
                end
            end
            
            if and
                progress == 11
                0611:   actor Fighter_2 performing_animation "Fight_uper"
            then
                0613: 1@ = actor Fighter_2 animation "Fight_uper" time
                if
                    1@ > 0.9
                then
                    progress = 12
                    0812: AS_actor Fighter_2 perform_animation "Fight_win" IFP "PedEventsMod" framedelta 2.0 loopA 0 lockX 1 lockY 1 lockF 0 time -1  // versionB
                end
            end
            
                if and
                progress == 12
                0611:   actor Fighter_2 performing_animation "Fight_win"
            then
                0613: 1@ = actor Fighter_2 animation "Fight_win" time
                if
                    1@ > 0.9
                then
                    progress = 3
                    034F: destroy_actor_with_fade Fighter_1
                    if
                        select == 2
                    then
                        money_1 *= 2
                        0109: player $PLAYER_CHAR money += money_1
                        money_1 /= 2
                        01E3: show_text_1number_styled GXT 'WINNER' number money_1 time 2000 style 5  // NEW HIGH SCORE!!~n~~w~~1~
                    else
                        00BA: show_text_styled GXT "NOWIN" time 2000 style 5  // Beefy Baron
                        03FE: set_actor Watcher_3 money money_1
                    end
                    break
                end
            end
            
        else
            break
        end
        until not locate_char_distance_to_coordinates $player_actor pos coords_x coords_y coords_z radius 150.0
        
        if
            locate_char_distance_to_coordinates $PLAYER_ACTOR pos coords_x coords_y coords_z radius 150.0
        then
            if 056D:   actor Fighter_1 defined
            then 01C2: remove_references_to_actor Fighter_1 // Like turning an actor into a random pedestrian
            end
            if 056D:   actor Fighter_2 defined
            then 01C2: remove_references_to_actor Fighter_2 // Like turning an actor into a random pedestrian
            end
            if 056D:   actor Watcher_1 defined
            then 01C2: remove_references_to_actor Watcher_1 // Like turning an actor into a random pedestrian
            end
            if 056D:   actor Watcher_2 defined
            then 01C2: remove_references_to_actor Watcher_2 // Like turning an actor into a random pedestrian
            end
            if 056D:   actor Watcher_3 defined
            then 01C2: remove_references_to_actor Watcher_3 // Like turning an actor into a random pedestrian
            end
        else
            if 056D:   actor Fighter_1 defined
            then 009B: destroy_actor Fighter_1
            end
            if 056D:   actor Fighter_2 defined
            then 009B: destroy_actor Fighter_2
            end
            if 056D:   actor Watcher_1 defined
            then 009B: destroy_actor Watcher_1
            end
            if 056D:   actor Watcher_2 defined
            then 009B: destroy_actor Watcher_2
            end
            if 056D:   actor Watcher_3 defined
            then 009B: destroy_actor Watcher_3
            end
        end
        04EF: release_animation "PedEventsMod"
        
        timera = 0
        repeat
        wait 0
        0ABC: set_audio_stream AudioMusic volume volume_1
        volume_1 -= 0.005
        until timera > 3000
        0AAE: remove_audio_stream AudioMusic
        
        repeat
        wait 0
        if and
            not locate_char_distance_to_coordinates $player_actor pos coords_x coords_y coords_z radius 150.0
            not progress > 0
        then
            break
        end
        until not locate_char_distance_to_coordinates $player_actor pos coords_x coords_y coords_z radius 300.0
        
0A93: terminate_this_custom_script

:Text
3@ /= 3.0
4@ /= 0.75
060D: draw_text_shadow 1 rgba 0 0 0 200
0342: set_text_draw_centered 1
0349: set_text_draw_font 2
033F: set_text_draw_letter_size 3@ 4@
033E: set_draw_text_position 1@ 2@ GXT 'STFGHQA'  // Push
03F0: enable_text_draw 0
return
